Jika Anda baru menggunakan Excel,
Anda akan menyadari Excel tidak hanya sekedar kisi di mana Anda
memasukkan angka dalam kolom atau baris. Ya, Anda bisa menggunakan Excel
untuk menemukan total untuk jumlah kolom atau baris, tapi Anda juga
bisa menghitung pembayaran hipotek, memecahkan perhitungan matematika
dan tehnik, atau menemukan pemecahan masalah terbaik berdasarkan jumlah
variabel yang Anda masukkan.
Excel melakukan semua ini menggunakan rumus dalam sel. Rumus membuat
perhitungan atau tindakan lainnya pada data dalam lembar kerja Anda.
Rumus selalu dimulai dengan tanda sama dengan (=), yang bisa diikuti
dengan angka, operator matematika (seperti tanda plus atau minus), dan
fungsi, yang benar-benar bisa memperluas kecanggihan rumus.
Misalnya, rumus berikut mengalikan 2 dengan 3 lalu menambahkan 5 ke hasil perkalian tersebut sehingga menghasilkan jawaban, 11.
=2*3+5
Rumus berikut ini menggunakan fungsi PMT untuk
menghitung pembayaran hipotek ($1,073.64), berdasarkan suku bunga 5
persen (5% dibagi dengan 12 bulan sama dengan suku bunga bulanan) dengan
lama pinjaman selama 30 tahun (360 bulan) untuk pinjaman sebesar
$200,000:
=PMT(0.05/12,360,200000)
Ini ada beberapa contoh tambahan yang bisa Anda masukkan dalam lembar kerja.
- =A1+A2+A3 Menambahkan nilai di sel A1, A2, dan A3.
- =SQRT(A1) Menggunakan fungsi SQRT untuk mendapatkan nilai akar kuadrat dalam A1.
- =TODAY() Mengembalikan tanggal saat ini.
- =UPPER("hello") Mengonversi teks "hello" menjadi "HELLO" dengan menggunakan fungsi lembar kerja UPPER.
- =IF(A1>0) Menguji sel A1 untuk mengetahui apakah sel A1 berisi nilai yang lebih besar dari 0.
Di artikel ini
Bagian-bagian rumus
Bagian-bagian rumus
Fungsi: PI() mengembalikan nilai dari pi: 3,142...
Referensi: A2 mengembalikan hasil dalam sel A2.
Konstanta: Nilai angka atau teks yang dimasukkan langsung ke rumus, misalnya 2.
Operator: operator
^ (sisipan) menaikkan angka ke pangkat, dan operator
* (tanda bintang) mengalikan angka.
Menggunakan konstanta dalam rumus
Konstanta adalah nilai yang tidak dihitung; nilainya selalu sama.
Misalnya, tanggal 10/9/2008, angka 210, dan teks "Pendapatan per
Kuartal" adalah konstanta. Sebuah
ekspresi
atau nilai yang dihasilkan dari ekspresi bukanlah merupakan konstanta.
Jika Anda menggunakan konstanta dalam rumus dan bukannya referensi untuk
sel (misalnya, =30+70+110), hasilnya akan berubah jika Anda mengubah
rumus.
Menggunakan operator perhitungan dalam rumus
Operator menentukan tipe perhitungan yang ingin Anda jalankan di
elemen sebuah rumus. Ada urutan default dalam perhitungan yang terjadi
(ini mengikuti aturan matematika umum), tapi Anda bisa mengubah urutan
ini dengan menggunakan tanda kurung.
Tipe-tipe operator
Ada empat tipe operator perhitungan yang berbeda: aritmetika, perbandingan, teks dan referensi.
Operator aritmetika
Untuk melakukan operasi matematika dasar, seperti penambahan,
pengurangan, perkalian, atau pembagian; menggabungkan angka; dan
menghasilkan nilai numerik, gunakan operator aritmetika berikut ini.
| Operator aritmetika |
Arti |
Contoh |
| + (tanda plus) |
Penjumlahan |
3+3 |
| – (tanda minus) |
Pengurangan
Negasi |
3–1
–1 |
| * (tanda bintang) |
Perkalian |
3*3 |
| / (tanda garis miring) |
Pembagian |
3/3 |
| % (tanda persen) |
Persen |
20% |
| ^ (tanda sisipan) |
Pangkat |
3^2 |
Operator perbandingan
Anda bisa membandingkan dua nilai dengan operator berikut ini. Saat
dua nilai dibandingkan dengan menggunakan operator ini, hasilnya adalah
nilai logika — TRUE atau FALSE.
| Operator perbandingan |
Arti |
Contoh |
| = (tanda sama dengan) |
Sama dengan |
A1=B1 |
| > (tanda lebih besar dari) |
Lebih besar dari |
A1>B1 |
| > (tanda lebih kecil dari) |
Lebih kecil dari |
A1<B1 |
| >= (tanda lebih besar dari atau sama dengan) |
Lebih besar dari atau sama dengan |
A1>=B1 |
| <= (tanda lebih kecil dari atau sama dengan) |
Lebih kecil atau sama dengan |
A1<=B1 |
| <> (tanda tidak sama dengan) |
Tidak sama dengan |
A1<>B1 |
Operator penggabungan teks
Gunakan lambang dan (&) untuk menggabungkan(gabungan) satu atau beberapa string teks untuk menghasilkan sebuah teks tunggal.
| Operator teks |
Arti |
Contoh |
| & (tanda dan) |
Menghubungkan, atau menggabungkan, dua nilai untuk menghasilkan satu nilai teks yang berkelanjutan |
"North"&"wind" menghasilkan "Northwind" |
Operator referensi
Menggabungkan rentang sel untuk perhitungan dengan operator berikut ini.
| Operator referensi |
Arti |
Contoh |
| : (titik dua) |
Operator rentang, yang menghasilkan satu referensi untuk semua sel antara dua referensi, termasuk kedua referensi. |
B5:B15 |
| , (koma) |
Operator gabungan, yang menggabungkan beberapa referensi menjadi satu referensi |
SUM(B5:B15,D5:D15) |
| (spasi) |
Operator irisan, yang menghasilkan satu referensi ke sel yang umumnya untuk dua referensi. |
B7:D7 C6:C8 |
Urutan Excel dalam melakukan operasi dalam rumus
Dalam beberapa kasus, urutan perhitungan yang dilakukan bisa
mempengaruhi nilai yang dihasilkan rumus, jadi sangat penting untuk
memahami bagaimana cara menentukan urutan dan bagaimana Anda bisa
mengubah urutan untuk mendapatkan hasil yang Anda inginkan.
Urutan perhitungan
Rumus menghitung nilai dalam susunan spesifik. Rumus di Excel selalu dimulai dengan tanda sama dengan (=).
Excel menganggap karakter setelah tanda sama dengan sebagai rumus.
Tanda sama dengan berikut ini adalah elemen untuk dihitung (operand),
seperti konstanta atau referensi sel. Ini dipisahkan oleh operator
perhitungan. Excel menghitung rumus dari kiri ke kanan, sesuai dengan
susunan tertentu untuk setiap operator dalam rumus tersebut.
Susunan operator
Jika Anda menggabungkan beberapa operator dalam satu rumus, Excel
menjalankan operasi dalam susunan yang diperlihatkan dalam tabel berikut
ini. Jika sebuah rumus berisi operator dengan susunan yang sama —
misalnya, jika rumus berisi operator perkalian dan operator pembagian —
Excel mengevaluasi operator dari kiri ke kanan.
| Operator |
Deskripsi |
: (titik dua)
(satu spasi)
, (koma)
|
Operator referensi |
| – |
Negasi (seperti di –1) |
| % |
Persen |
| ^ |
Pangkat |
| * dan / |
Perkalian dan pembagian |
| + dan – |
Penjumlahan dan pengurangan |
| & |
Menyambungkan dua string teks (penggabungan) |
=
< >
<=
>=
<> |
Perbandingan |
Penggunaan tanda dalam kurung
Untuk mengubah susunan evaluasi, bagian rumus yang dimasukkan dalam
kurung harus dihitung terlebih dahulu. Misalnya, rumus berikut ini
menghasilkan 11 karena Excel melakukan perkalian sebelum penambahan.
Rumus tersebut mengalikan 2 dengan 3 lalu menambahkan 5 ke hasil
tersebut.
=5+2*3
Sebaliknya, jika Anda menggunakan tanda kurung untuk mengubah
sintaks, Excel menjumlahkan 5 dan 2 bersamaan lalu mengalikan hasilnya
dengan 3 untuk menghasilkan 21.
=(5+2)*3
Dalam contoh berikut ini, tanda kurung yang menampung bagian pertama
rumus memaksa Excel untuk menghitung B4+25 terlebih dahulu lalu membagi
hasilnya dengan menjumlahkan nilai dalam sel D5, E5, dan F5.
=(B4+25)/SUM(D5:F5)
Menggunakan fungsi dan fungsi yang ditumpuk dalam rumus
Fungsi merupakan rumus yang telah ditetapkan sebelumnya yang
menjalankan perhitungan dengan menggunakan nilai tertentu, yang disebut
argumen, dalam susunan tertentu, atau struktur. Fungsi bisa digunakan
untuk menjalankan perhitungan sederhana atau kompleks.
Sintaks fungsi
Contoh berikut dari fungsi ROUND membulatkan angka dalam sel A10 mengilustrasikan sintaks fungsi.
Struktur fungsi
Struktur. Struktur fungsi dimulai dengan tanda sama dengan (
=), yang diikuti dengan nama fungsi, tanda kurung buka, argumen untuk fungsi yang dipisahkan oleh koma, dan tanda kurung tutup.
Nama fungsi. Untuk daftar fungsi yang ada, klik sel dan tekan SHIFT+F3.
Argumen. Argumen bisa berupa angka, teks, nilai logika seperti TRUE atau FALSE,
array, nilai kesalahan seperti #N/A, atau
referensi sel. Argumen yang Anda tentukan harus menghasilkan nilai yang valid untuk argumen itu. Argumen juga bisa berupa
konstanta, rumus, atau fungsi lainnya.
Argumen tips alat. Tips alat dengan sintaks dan argumen muncul saat Anda mengetikkan fungsi. Misalnya, ketik
=ROUND( dan tips alat akan muncul. Tips alat hanya muncul untuk fungsi bawaan.
Memasukkan fungsi
Ketika Anda membuat rumus yang berisi fungsi, Anda bisa menggunakan kotak dialog Sisipkan Fungsi untuk membantu Anda memasukkan fungsi lembar kerja. Saat Anda memasukkan fungsi ke dalam rumus, kotak dialog Sisipkan Fungsi
menampilkan nama fungsi, setiap argumen fungsi, deskripsi fungsi dan
setiap argumen, hasil fungsi saat ini, dan hasil seluruh rumus terbaru.
Untuk lebih memudahkan membuat dan mengedit rumus dan mengurangi
kesalahan pengetikan dan sintaks, gunakan Rumus LengkapiOtomatis.
Setelah Anda mengetik = (tanda sama dengan) dan huruf awal atau
menampilkan pemicu, Excel menampilkan, di bawah sel, daftar turun bawah
dinamis dari fungsi, argumen dan nama yang cocok dengan huruf dan
pemicu. Kemudian Anda bisa menyisipkan item dari daftar turun bawah ke
dalam rumus.
Fungsi yang ditumpuk
Dalam kasus tertentu, Anda mungkin perlu menggunakan fungsi sebagai salah satu
argumen fungsi lainnya. Misalnya, rumus berikut ini menggunakan fungsi
AVERAGE yang ditumpuk dan membandingkan hasil dengan nilai 50.
Fungsi AVERAGE dan SUM ditumpuk di dalam fungsi IF.
Hasil yang valid Ketika fungsi yang
ditumpuk digunakan sebagai argumen, fungsi yang ditumpuk harus
menghasilkan nilai tipe yang sama dengan yang digunakan argumen.
Misalnya, jika argumen menghasilkan nilai TRUE atau FALSE, fungsi yang
ditumpuk harus menghasilkan nilai TRUE atau FALSE. Jika fungsi tidak
menampilkan nilai yang sama, Excel menampilkan nilai kesalahan #VALUE!.
Batas tingkat penumpukan Rumus bisa
memuat hingga delapan tingkat fungsi yang ditumpuk. Ketika satu fungsi
(kita akan menyebut ini Fungsi B) digunakan sebagai argumen dalam fungsi
lain (kita menyebut ini Fungsi A), Fungsi B bertindak sebagai fungsi
tingkat kedua. Misalnya, fungsi AVERAGE dan fungsi SUM merupakan fungsi tingkat kedua jika keduanya digunakan sebagai argumen dari fungsi IF. Fungsi yang ditumpuk di dalam fungsi AVERAGE akan menjadi fungsi tingkat ketiga, dan seterusnya.
Menggunakan referensi dalam rumus
Referensi mengidentifikasi sel atau rentang sel di lembar kerja, dan
memberitahu Excel di mana mencari nilai atau data yang ingin Anda
gunakan dalam rumus. Anda bisa menggunakan referensi untuk menggunakan
data yang berada di bagian yang berbeda dari lembar kerja dalam satu
rumus atau menggunakan nilai dari satu sel dalam beberapa rumus. Anda
juga bisa merujuk ke sel pada lembar lainnya dalam lembar kerja yang
sama, dan ke buku kerja lainnya. Referensi ke sel dalam buku kerja
lainnya disebut link atau
referensi eksternal.
Gaya referensi A1
Gaya referensi default Secara default,
Excel menggunakan gaya referensi A1, yang merujuk ke kolom dengan huruf
(A hingga XFD, dengan total kolom 16,384) dan merujuk pada baris dengan
angka (1 hingga 1.048.576). Huruf dan angka ini disebut judul baris dan
kolom. Untuk merujuk ke sel, masukkan huruf kolom diikuti dengan angka
baris. Misalnya, B2 merujuk ke sel irisan dari kolom B dan baris 2.
| Untuk merujuk ke |
Gunakan |
| Sel dalam kolom A dan baris 10 |
A10 |
| Rentang sel dalam kolom A dan baris 10 hingga 20 |
A10:A20 |
| Rentang sel dalam baris 15 dan kolom B hingga E |
B15:E15 |
| Semua sel dalam baris 5 |
5:5 |
| Semua sel dalam baris 5 hingga 10 |
5:10 |
| Semua sel dalam kolom H |
H:H |
| Semua sel dalam kolom H hingga J |
H:J |
| Rentang sel dalam kolom A hingga E dan baris 10 hingga 20 |
A10:E20 |
Membuat referensi ke lembar kerja lain Dalam contoh berikut ini, fungsi lembar kerja AVERAGE menghitung nilai rata-rata untuk rentang B1:B10 pada lembar kerja yang dinamai Marketing dalam buku kerja yang sama.
Referensi untuk rentang sel di lembar kerja lain dalam buku kerja yang sama
Merujuk ke lembar kerja bernama Marketing
Merujuk ke rentang sel antara dan mencakup B1 dan B10
Memisahkan referensi lembar kerja dari referensi rentang sel
Perbedaan antara referensi absolut, relatif dan campuran
Referensi relatif Referensi sel relatif
dalam rumus, seperti A1, didasarkan pada posisi relatif dari sel yang
berisi rumus dan sel yang dirujuk referensi. Jika posisi sel yang berisi
rumus berubah, referensi berubah. Jika Anda menyalin atau mengisi rumus
baris mendatar atau kolom menurun, referensi menyesuaikan secara
otomatis. Secara default, rumus baru menggunakan referensi relatif.
Misalnya, jika Anda menyalin atau mengisi referensi relatif dalam sel B2
ke sel B3, referensi disesuaikan secara otomatis dari =A1 ke =A2.
Menyalin rumus dengan referensi relatif
Referensi absolut Referensi sel absolut
dalam rumus, seperti $A$1, selalu merujuk ke sel dalam lokasi tertentu.
Jika posisi sel yang berisi rumus berubah, referensi absolut tetap sama.
Jika Anda menyalin atau mengisi baris mendatar atau kolom menurun,
referensi absolut tidak disesuaikan. Secara default, rumus baru
menggunakan referensi relatif , jadi Anda mungkin harus mengubahnya
menjadi referensi absolut. Misalnya, jika Anda menyalin atau mengisi
referensi absolut dalam sel B2 ke cell B3, referensi tetap sama dalam
kedua sel: =$A$1.
Menyalin rumus dengan referensi absolut
Referensi campuran Referensi campuran
memiliki kolom absolut dan baris relatif, atau baris absolut dan kolom
relatif. Kolom referensi absolut berupa $A1, $B1, dan seterusnya. Baris
referensi absolut berupa A$1, B$1, dan seterusnya. Jika posisi sel yang
berisi rumus berubah, referensi relatif juga berubah, dan referensi
absolut tidak berubah. Jika Anda menyalin rumus baris mendatar dan kolom
menurun, referensi relatif disesuaikan secara otomatis, dan referensi
absolut tidak disesuaikan secara otomatis. Contohnya, jika Anda menyalin
atau mengisi referensi campuran dari sel A2 ke B3, referensi
disesuaikan dari =A$1 ke =B$1.
Menyalin rumus dengan referensi campuran
Gaya referensi 3-D
Mereferensikan beberapa lembar kerja dengan nyaman Jika
Anda ingin menganalisa data dalam sel yang sama atau rentang sel di
beberapa lembar kerja di dalam buku kerja, gunakan referensi 3-D.
Referensi 3-D termasuk referensi sel atau rentang, didahului dengan nama
lembar kerja. Excel menggunakan semua lembar kerja yang disimpan di
antara nama awal dan nama akhir referensi. Misalnya,
=SUM(Sheet2:Sheet13!B5) menambahkan semua nilai yang terdapat di sel B5
pada semua lembar kerja di antara dan termasuk Lembar 2 dan Lembar 13.
- Anda bisa menggunakan referensi 3-D untuk merujuk ke sel di lembar
lain, untuk menentukan nama, dan untuk membuat rumus dengan menggunakan
fungsi berikut ini: SUM, AVERAGE, AVERAGEA, COUNT, COUNTA, MAX, MAXA,
MIN, MINA, PRODUCT, STDEV.P, STDEV.S, STDEVA, STDEVPA, VAR.P, VAR.S,
VARA, dan VARPA.
- Referensi 3-D tidak bisa digunakan dalam rumus array.
- Referensi 3-D tidak bisa digunakan dengan operator irisan (satu spasi) atau dalam rumus yang menggunakan irisan implisit.
Apa yang terjadi ketika Anda memindahkan, menyalin, menyisipkan, atau menghapus lembar kerja Contoh
berikut ini menjelaskan apa yang terjadi ketika Anda memindahkan,
menyalin, menyisipkan, atau menghapus lembar kerja yang termasuk dalam
referensi 3-D. Contoh yang menggunakan rumus =SUM(Sheet2:Sheet6!A2:A5)
untuk menambahkan sel A2 hingga A5 pada lembar kerja 2 hingga 6.
- Sisipkan atau salin Jika Anda
menyisipkan atau menyalin lembar kerja antara Sheet2 dan Sheet6 (titik
akhir dalam contoh ini), Excel akan memasukkan semua nilai dalam sel A2
sampai A5 dari lembar kerja yang ditambahkan dalam perhitungan.
- Hapus Jika Anda menghapus lembar antara Sheet2 dan Sheet6, Excel akan menghapus nilainya dari perhitungan.
- Pindahkan Jika Anda memindahkan
lembar dari antara Sheet2 dan Sheet6 ke lokasi di luar rentang lembar
yang dirujuk, Excel akan menghapus nilainya dari perhitungan.
- Pindahkan titik akhir Jika Anda
memindahkan Sheet2 atau Sheet6 ke lokasi lain di buku kerja yang sama,
Excel menyesuaikan perhitungan untuk mengakomodasi rentang baru lembar
antara keduanya.
- Hapus titik akhir Jika Anda menghapus
Sheet2 atau Sheet6, Excel menyesuaikan perhitungan untuk mengakomodasi
rentang baru lembar antara keduanya.
Gaya referensi R1C1
Anda juga bisa menggunakan gaya referensi di mana kedua baris dan
kolom pada lembar kerja bernomor. Gaya Referensi R1C1 berguna untuk
komputasi posisi baris dan kolom dalam
makro. Dalam gaya R1C1, Excel menunjukkan lokasi sel dengan "R" diikuti oleh jumlah baris dan "C" diikuti oleh jumlah kolom.
| Referensi |
Arti |
| R[-2]C |
Referensi relatif ke sel dua baris ke atas dan dalam kolom yang sama |
| R[2]C[2] |
Referensi relatif ke sel dua baris ke bawah dan dua kolom ke kanan |
| R2C2 |
Referensi absolut ke sel dalam baris kedua dan dalam kolom kedua. |
| R[-1] |
Referensi relatif ke seluruh baris di atas sel aktif |
| R |
Referensi absolut ke baris saat ini |
Ketika Anda merekam makro, Excel merekam beberapa perintah dengan
menggunakan gaya referensi R1C1. Misalnya, jika Anda merekam perintah,
seperti mengklik tombol AutoSum untuk menyisipkan
rumus yang menambahkan rentang sel, Excel merekam rumus dengan
menggunakan gaya referensi R1C1, bukan gaya referensi A1.
Anda bisa mengaktifkan atau menonaktifkan gaya referensi R1C1 dengan mencentang atau mengosongkan kotak centang gaya referensi R1C1di bawah bagian Bekerja dengan rumus dalam kategori Rumus di kotak dialog Opsi. Untuk menampilkan kotak dialog ini, klik tab File.
Menggunakan nama dalam rumus
Anda bisa membuat
nama
yang ditentukan untuk mewakili sel, rentang sel, rumus, konstanta, atau
tabel Excel. Nama adalah singkatan bermakna yang memudahkan untuk
memahami tujuan suatu referensi sel, konstanta, rumus, atau tabel, yang
akan sulit untuk dipahami secara sekilas. Informasi berikut ini
memperlihatkan contoh-contoh umum nama dan bagaimana menggunakannya
dalam rumus bisa meningkatkan kejelasan dan membuat rumus lebih mudah
dipahami.
| Tipe contoh |
Contoh, menggunakan rentang dan bukan nama |
Contoh, menggunakan nama |
| Referensi |
=SUM(A16:A20) |
=SUM(Sales) |
| Konstanta |
=PRODUCT(A12,9.5%) |
=PRODUCT(Price,KCTaxRate) |
| Rumus |
=TEXT(VLOOKUP(MAX(A16,A20),A16:B20,2,FALSE),"m/dd/yyyy") |
=TEXT(VLOOKUP(MAX(Sales),SalesInfo,2,FALSE),"m/dd/yyyy") |
| Tabel |
A22:B25 |
=PRODUCT(Price,Table1[@Tax Rate]) |
Contoh dalam lembar kerja
Salin contoh data di dalam tabel berikut ini dan tempel ke dalam sel
A1 lembar kerja Excel yang baru. Agar rumus memperlihatkan hasil, pilih
datanya, tekan F2, lalu tekan Enter. Jika perlu, Anda bisa menyesuaikan
lebar kolom untuk melihat semua data.
| Tipe contoh |
Contoh, tidak menggunakan nama |
Contoh, menggunakan nama |
Rumus dan hasilnya, menggunakan nama |
| Referensi |
'=SUM(A9:A13) |
'=SUM(Sales) |
=SUM(Sales) |
| Rumus |
'=TEXT(VLOOKUP(MAX(A9:13),A9:B13,2,FALSE),"m/dd/yyyy") |
'=TEXT(VLOOKUP(MAX(Sales),SalesInfo,2,FALSE),"m/dd/yyyy") |
=TEXT(VLOOKUP(MAX(Sales),SalesInfo,2,FALSE),"m/dd/yyyy") |
| |
|
|
|
| Harga |
|
|
|
| $995 |
|
|
|
| |
|
|
|
| Penjualan |
Tanggal Penjualan |
|
|
| $249 |
17/3/2011 |
|
|
| $399 |
2/4/2011 |
|
|
| $643 |
23/4/2011 |
|
|
| $275 |
30/4/2011 |
|
|
| $447 |
5/4/2011 |
|
|
Catatan: Dalam rumus di kolom C dan D, nama yang ditentukan "Sales"
menggantikan referensi ke (rentang) A9:A13 dan nama "SalesInfo"
menggantikan rentang A9:B13.
Tipe-tipe nama
Ada beberapa tipe nama yang bisa Anda buat dan gunakan.
Nama yang ditentukan Nama mewakili nilai
sel, rentang sel, rumus, atau konstanta. Anda bisa membuat sendiri nama
yang ditentukan. Juga, Excel kadang-kadang membuat nama yang ditentukan
untuk Anda, seperti ketika Anda mengatur area cetak.
Nama tabel Nama untuk tabel Excel, yang
merupakan koleksi data mengenai subjek tertentu yang disimpan dalam
rekaman (baris) dan bidang (kolom). Excel membuat nama tabel default
Excel Table1, Table2, dan seterusnya, setiap kali Anda menyisipkan tabel
Excel, tapi Anda bisa mengubah nama ini untuk membuatnya lebih
bermakna.
Membuat dan memasukkan nama
Anda membuat nama dengan menggunakan:
- Kotak nama pada bilah rumus Ini paling cocok digunakan untuk membuat nama tingkat buku kerja untuk rentang terpilih.
- Buat nama dari pilihan Anda bisa
membuat nama dengan nyaman dari label baris dan kolom yang telah ada
dengan menggunakan pilihan sel dalam buku kerja.
- Kotak dialog Nama Baru Ini cara
terbaik apabila Anda menginginkan fleksibilitas dalam membuat nama,
misalnya menentukan lingkup tingkat lembar kerja atau membuat komentar
nama.
Anda bisa memasukkan nama dengan:
- Ketik Ketikkan nama, misalnya, sebagai argumen untuk rumus.
- Menggunakan Rumus LengkapiOtomatis Gunakan Rumus LengkapiOtomatis daftar turun bawah, di mana nama yang valid secara otomatis dicantumkan untuk Anda.
- Memilih dari perintah Gunakan dalam Rumus Pilih nama yang ditentukan dari daftar yang tersedia di perintah Gunakan dalan Rumus dalam grup Nama yang Ditentukan pada tab Rumus.
Menggunakan rumus array dan konstanta array
Rumus array bisa menjalankan beberapa perhitungan dan menghasilkan
satu hasil atau beberapa hasil. Rumus array dijalankan pada dua atau
beberapa set nilai yang dikenal sebagai argumen array. Setiap argumen
array harus memiliki jumlah baris dan kolom yang sama. Anda membuat
rumus array dengan cara yang sama yang Anda gunakan untuk membuat rumus
yang lain, kecuali Anda menekan CTRL+SHIFT+ENTER untuk memasukkan rumus.
Beberapa fungsi bawaan merupakan rumus array, dan harus dimasukkan
sebagai array untuk mendapatkan hasil yang tepat.
Konstanta array bisa digunakan dalam tempat yang direferensikan
ketika Anda tidak ingin memasukkan setiap nilai konstanta dalam sel yang
terpisah pada lembar kerja.
Gunakan rumus array untuk menghitung satu hasil atau beberapa hasil
Ketika Anda memasukkan
rumus array, Excel secara otomatis menyisipkan rumus di antara { } (kurung kurawal).
Untuk menghitung satu hasil Tipe rumus
array ini bisa menyederhanakan model buku kerja dengan mengganti
beberapa rumus yang berbeda dengan satu rumus array.
Contohnya, rumus berikut menghitung nilai total array harga dan
jumlah saham, tanpa menggunakan baris sel untuk menghitung dan
menampilkan nilai individual untuk setiap saham.
Rumus array yang menghasilkan sebuah hasil
Ketika Anda memasukkan ={SUM(B2:D2*B3:D3)} sebagai rumus array, rumus
mengalikan Jumlah dan Harga untuk setiap saham, lalu menambahkan hasil
perhitungan tersebut sekaligus.
Untuk menghitung beberapa hasil Beberapa
fungsi buku kerja menghasilkan nilai array, atau membutuhkan nilai array
sebagai argumen. Untuk menghitung beberapa hasil dengan rumus array,
Anda harus memasukan array ke dalam rentang sel yang memiliki jumlah
baris dan kolom yang sama dengan argumen array.
Misalnya, adanya seri tiga angka penjualan (dalam kolom B) untuk seri tiga bulan (dalam kolom A), fungsi TREND
menentukan nilai langsung untuk angka penjualan tersebut. Untuk
menampilkan semua hasil rumus, semuanya dimasukkan ke dalam tiga sel di
dalam kolom C (C1:C3).
Rumus array yang menghasilkan beberapa hasil
Saat Anda memasukkan rumus =TREND(B1:B3,A1:A3) sebagai rumus array,
rumus menghasilkan tiga hasil terpisah (22196, 17079, dan 11962),
didasarkan pada tiga angka penjualan dan tiga bulan.
Menggunakan konstanta array
Dalam rumus biasa, Anda bisa memasukkan referensi ke sel yang berisi
nilai, atau nilai itu sendiri, juga disebut konstanta. Begitu juga,
dalam rumus array Anda bisa memasukkan referensi ke array, atau
memasukkan nilai yang dimuat dalam sel, juga disebut konstanta array.
Rumus menerima konstanta dalam cara yang sama yang dilakukan rumus non
array, Anda harus memasukkan konstanta array dalam format tertentu.
Konstanta array bisa berisi angka, teks, nilai logika seperti TRUE
atau FALSE, atau nilai kesalahan seperti #N/A. Tipe-tipe nilai yang
berbeda bisa berada di konstanta array yang berbeda — misalnya,
{1,3,4;TRUE,FALSE,TRUE}. Jumlah konstanta array bisa berupa bilangan
bulat, desimal, atau format ilmiah. Teks harus dimasukkan dalam tanda
petik ganda — misalnya, "Selasa".
Konstanta array tidak boleh berisi referensi sel, kolom atau baris
yang panjangnya tidak sama, rumus, atau karakter khusus $ (tanda dolar),
tanda kurung atau % (tanda persen).
Ketika Anda memformat konstanta array, pastikan Anda:
- Memasukkannya dalam kurung kurawal ( { } ).
- Memisahkan nilai dalam kolom yang berbeda dengan menggunakan koma (,).
Misalnya, untuk mewakili nilai 10, 20, 30, dan 40, Anda memasukkan
{10,20,30,40}. Konstanta array ini dikenal sebagai array 1 kali 4 dan
sama dengan referensi 1-baris-kali-4-kolom.
- Memisahkan nilai dalam baris yang berbeda dengan menggunakan titik koma(;).
Misalnya, untuk mewakili nilai 10, 20, 30, dan 40 dalam satu baris dan
50, 60, 70, dan 80 dalam baris tepat di bawahnya, Anda memasukkan
konstanta 2 kali 4: {10,20,30,40;50,60,70,80}.
Atas Halaman
